onClipEvent()

Availability

Flash Player 5.

Usage

onClipEvent(movieEvent){
  // your statements here
}

Parameters

A movieEvent is a trigger called an event. When the event takes place, the statements following it within curly braces are executed. Any of the following values can be specified for the movieEvent parameter:

• load The action is initiated as soon as the movie clip is instantiated and appears in the Timeline.
• unload The action is initiated in the first frame after the movie clip is removed from the Timeline. The actions associated with the Unload movie clip event are processed before any actions are attached to the affected frame.
• enterFrame The action is triggered continually at the frame rate of the movie clip. The actions associated with the enterFrame clip event are processed before any frame actions that are attached to the affected frames.
• mouseMove The action is initiated every time the mouse is moved. Use the _xmouse and _ymouse properties to determine the current mouse position.
• mouseDown The action is initiated when the left mouse button is pressed.
• mouseUp The action is initiated when the left mouse button is released.
• keyDown The action is initiated when a key is pressed. Use Key.getCode() to retrieve information about the last key pressed.
• keyUp The action is initiated when a key is released. Use the Key.getCode() method to retrieve information about the last key pressed.
• data The action is initiated when data is received in a loadVariables() or loadMovie() action. When specified with a loadVariables() action, the data event occurs only once, when the last variable is loaded. When specified with a loadMovie() action, the data event occurs repeatedly, as each section of data is retrieved.

Description

Event handler; triggers actions defined for a specific instance of a movie clip.

Example

The following statement includes the script from an external file when the SWF file is exported; the actions in the included script are run when the movie clip they are attached to loads:

onClipEvent(load) {
  #include "myScript.as"
}

The following example uses onClipEvent() with the keyDown movie event. The keyDown movie event is usually used in conjunction with one or more methods and properties of the Key object. The following script uses Key.getCode() to find out which key the user has pressed; if the pressed key matches the Key.RIGHT property, the movie is sent to the next frame; if the pressed key matches the Key.LEFT property, the movie is sent to the previous frame.

onClipEvent(keyDown) {
  if (Key.getCode() == Key.RIGHT) {
    _parent.nextFrame();
  } else if (Key.getCode() == Key.LEFT){
    _parent.prevFrame();
  }
}

The following example uses onClipEvent() with the mouseMove movie event. The _xmouse and _ymouse properties track the position of the mouse each time the mouse moves.

onClipEvent(mouseMove) {
  stageX=_root._xmouse;
  stageY=_root._ymouse;
}

See also

Key class, MovieClip._xmouse, MovieClip._ymouse, on(), updateAfterEvent()