| |
| |
| |
| |
Flash Player 6.
receiving_lc.connect(connectionName)
connectionName A string that corresponds to the connection name specified in the LocalConnection.send() command that wants to communicate with receiving_lc.
A Boolean value of true if no other process running on the same client machine has already issued this command using the same value for the connectionName parameter, false otherwise.
Method; prepares a LocalConnection object to receive commands from a LocalConnection.send() command (called the "sending LocalConnection object"). The object used with this command is called the "receiving LocalConnection object." The receiving and sending objects must be running on the same client machine.
Be sure to define the methods attached to receiving_lc before calling this method, as shown in all the examples in this section.
By default, the Flash Player resolves connectionName into a value of "superdomain:connectionName", where superdomain is the superdomain of the SWF file containing the LocalConnection.connect() command. For example, if the SWF file containing the receiving LocalConnection object is located at www.someDomain.com, connectionName resolves to "someDomain.com:connectionName". (If a SWF file is located on the client machine, the value assigned to superdomain is "localhost".)
Also by default, the Flash Player lets the receiving LocalConnection object accept commands only from sending LocalConnection objects whose connection name also resolves into a value of "superdomain:connectionName". In this way, Flash makes it very simple for SWF files located in the same domain to communicate with each other.
If you are implementing communication only between SWF files in the same domain, specify a string for connectionName that does not begin with an underscore (_) and that does not specify a domain name (for example, "myDomain:connectionName"). Use the same string in the LocalConnection.connect(connectionName) command.
If you are implementing communication between SWF files located in different domains, see the discussion of connectionName in LocalConnection.send(), and also the LocalConnection.allowDomain and LocalConnection.domain() entries.
The following example shows how a SWF file in a particular domain can invoke a method named Trace in a receiving SWF file in the same domain. The receiving SWF file functions as a trace window for the sending SWF file; it contains two methods that other SWF files can call—Trace and Clear. Buttons pressed in the sending SWF files call these methods with specified parameters.
// Receiving SWF
var aLocalConnection = new LocalConnection();
aLocalConnection.Trace = function(aString)
{
aTextField = aTextField + aString + newline;
}
aLocalConnection.Clear = function()
{
aTextField = "";
}
aLocalConnection.connect("trace");
stop();
SWF 1 contains the following code attached to a button labeled PushMe. When you push the button, you see the sentence "The button was pushed." in the receiving SWF file.
on (press)
{
var lc = new LocalConnection();
lc.send("trace", "Trace", "The button was pushed.");
delete lc;
}
SWF 2 contains an input text box with a var name of myText, and the following code attached to a button labeled Copy. When you type some text and then push the button, you see the text you typed in the receiving SWF file.
on (press)
{
_parent.lc.send("trace", "Trace", _parent.myText);
_parent.myText = "";
}
SWF 3 contains the following code attached to a button labeled Clear. When you push the button, the contents of the trace window in the receiving SWF file are cleared (erased).
on (press)
{
var lc = new LocalConnection();
lc.send("trace", "Clear");
delete lc;
}
| |
| |
| |
| |